چهارشنبه، آبان ۰۶، ۱۳۸۳

Simulating keystrokes from code 


procedure PostKeyEx32(key: Word; const shift: TShiftState; specialkey: Boolean) ;

پارامترها:
Key
کد انسی مروبط به کلیدی که می خواهید فشرده شدن آنرا شبیه سازی کنید
Shift
مشخص کننده وضعیت کلید شیفت
SpecialKey
معمولا باید مقدار نادرست را برای این پارمتر در نظر گرفت مگر اینکه بخواهید بخش کی پد را شبیه سازی کنید. 


type

   TShiftKeyInfo = record

     shift: Byte ;

     vkey: Byte ;

   end;

   ByteSet = set of 0..7 ;

const

   shiftkeys: array [1..3] of TShiftKeyInfo =

     ((shift: Ord(ssCtrl) ; vkey: VK_CONTROL),

     (shift: Ord(ssShift) ; vkey: VK_SHIFT),

     (shift: Ord(ssAlt) ; vkey: VK_MENU)) ;

var

   flag: DWORD;

   bShift: ByteSet absolute shift;

   j: Integer;

begin

   for j := 1 to 3 do

   begin

     if shiftkeys[j].shift in bShift then

       keybd_event(shiftkeys[j].vkey, MapVirtualKey(shiftkeys[j].vkey, 0), 0, 0) ;

   end;

   if specialkey then

     flag := KEYEVENTF_EXTENDEDKEY

   else

     flag := 0;



   keybd_event(key, MapvirtualKey(key, 0), flag, 0) ;

   flag := flag or KEYEVENTF_KEYUP;

   keybd_event(key, MapvirtualKey(key, 0), flag, 0) ;



   for j := 3 downto 1 do

   begin

     if shiftkeys[j].shift in bShift then

       keybd_event(shiftkeys[j].vkey, MapVirtualKey(shiftkeys[j].vkey, 0), KEYEVENTF_KEYUP, 0) ;

   end;

end;


برای استفاده از تابع بالا می توانید از مثال زیر استفاده کنید 


~~~~~~~~~~~~~~~~~~~~~~~~~

Example of usage:

~~~~~~~~~~~~~~~~~~~~~~~~~

procedure TForm1.SpeedButton1Click(Sender: TObject) ;

begin

// Simulate PRINTSCREEN - snapshot of the full screen

PostKeyEx32(VK_SNAPSHOT, [], False) ;



// Simulate PRINTSCREEN - snapshot of the active window

PostKeyEx32(VK_SNAPSHOT, [ssAlt], False) ;



// Simulate left Windows key

PostKeyEx32(VK_LWIN, [], False) ;



// Simulate Alt+F4 - close active window

PostKeyEx32(VK_F4, [ssAlt], False) ;

end;


Delphi Teacher
at

هیچ نظری موجود نیست:

ارسال یک نظر